home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / TEX-UTIL / DVIVIEW / TEXFONTS5 / !TeXFonts / NotRISCOS / italig / mf
Text File  |  1988-02-26  |  10KB  |  200 lines
  1. % This is ITALIG.MF in text format, as of Mar 31, 1986.
  2. % This file describes five italic ligatures that begin with `f'
  3. % and puts them in code positions \0013--\0017.
  4.  
  5. numeric itc; % modified italic correction on `f' and `ff'
  6. itc=(asc_height#-x_height#)*slant+.75u#;
  7.  
  8. ligtable "f": "i"=:oct"014", "f"=:oct"013", "l"=:oct"015",
  9.  "'" kern itc, "?" kern itc, "!" kern itc, ")" kern itc, "]" kern itc;
  10. ligtable oct"013": "i"=:oct"016", "l"=:oct"017",
  11.  "'" kern itc, "?" kern itc, "!" kern itc, ")" kern itc, "]" kern itc;
  12.  
  13. cmchar "Italic ligature ff";
  14. beginchar(oct"013",5u#+max(1.5u#,stem#)+max(3.5u#,2flare#)+2letter_fit#,
  15.  asc_height#,desc_depth#);
  16. italcorr asc_height#*slant+.75u#;
  17. adjust_fit(0,0); pickup fine.nib;
  18. z98-z88=z99-z89=z14-z4=z15-z5=(4.8u+2letter_fit,0);
  19. .5[x88,x99]=.5w-.1u; x89-x88=u; y98=h; y99=-d;
  20. numeric theta; theta=angle(z88-z89);
  21. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  22. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  23. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  24. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  25. rt x1r=hround(.5w+1.25u); lft x8r=hround-.35u; x2=.5[x1,x4]; x7=.6[x8,x5];
  26. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  27. y4=.25[x_height,h]; y5=.5[-d,y4];
  28. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  29. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  30. bulb(2,1,0); bulb(7,8,9);  % left bulbs
  31. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper middle arc
  32. filldraw z4r--z5l--z5r--z4l--cycle;  % left stem
  33. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower left arc
  34. pos10(flare,0); pos11(hair,0); pos12(vair,90);
  35. pos13(.5[hair,stem],180); pos14(stem,theta+90);
  36. pos15(stem,theta-90); pos16(.5[hair,stem],0);
  37. pos17(vair,-90); pos18(hair,-180); pos19(flare,-180);
  38. rt x11r=hround(w+.25u); lft x18r=hround(.5w-1.25u);
  39. x12=.6[x11,x14]; x17=.5[x18,x15];
  40. x13=.8[x12+x14-x98,x98]; x16=.8[x17+x15-x99,x99];
  41. y0=y10; y2=y12; y3=y13; y6=y16; y7=y17; y9=y19;
  42. bulb(12,11,10); bulb(17,18,19);  % right bulbs
  43. filldraw stroke z12e{left}...z13e...{z99-z98}z14e;  % upper right arc
  44. filldraw z14r--z15l--z15r--z14l--cycle;  % right stem
  45. filldraw stroke z15e{z99-z98}...z16e...{left}z17e;  % lower middle arc
  46. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  47. top y20r=top y21r=x_height;
  48. lft x20=lft x4r-.5stem-u; rt x21=rt x14l+.5stem+1.5u;
  49. filldraw stroke z20e--z21e;  %  crossbar
  50. penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,
  51.  20,21,88,89,98,99); endchar;
  52.  
  53. cmchar "Italic ligature fi";
  54. beginchar(oct"014",6.5u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
  55.  +2letter_fit#,asc_height#,desc_depth#);
  56. italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
  57. adjust_fit(0,0); pickup fine.nib;
  58. .5[x88,x89]=.5(w-4u-2letter_fit); x89-x88=u; y88=h; y89=-d;
  59. numeric theta; theta=angle(z88-z89);
  60. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  61. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  62. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  63. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  64. pos11(stem,0); rt x11r=hround(w-2.5u+.5stem);
  65. x12=x11; x14=w; hook_out(12,13,14);  % closing hook
  66. x1r=x11r; lft x8r=hround-.35u; x2=.5[x1,x4]; x7=.6[x8,x5];
  67. y9-.5flare=vround-.85d; bot y7r=-d-oo;
  68. y0+.5flare=vround(.85[x_height,h]); top y2r=h+oo;
  69. y4=.25[x_height,h]; y5=.5[-d,y4];
  70. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  71. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  72. bulb(2,1,0); bulb(7,8,9);  % bulbs
  73. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
  74. filldraw z4r--z5l--z5r--z4l--cycle;  % left stem
  75. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
  76. top y11=x_height; filldraw stroke z11e--z12e;  % right stem
  77. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  78. top y20r=top y21r=x_height;
  79. lft x20=lft x4r-.5stem-u; x21=x11;
  80. filldraw stroke z20e--z21e;  %  crossbar
  81. penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,20,21,88,89); endchar;
  82.  
  83. cmchar "Italic ligature fl";
  84. beginchar(oct"015",7u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
  85.  +2letter_fit#,asc_height#,desc_depth#);
  86. italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
  87. adjust_fit(0,0); pickup fine.nib;
  88. .5[x88,x89]=.5(w-4.5u-2letter_fit); x89-x88=u; y88=h; y89=-d;
  89. numeric theta; theta=angle(z88-z89);
  90. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  91. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  92. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  93. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  94. pos11(stem,0); rt x11r=hround(w-2.5u+.5stem); rt x1r=lft x11l;
  95. x12=x11; x14=w; hook_out(12,13,14);  % closing hook
  96. lft x8r=hround-.35u; x2=.5[x1,x4]; x7=.6[x8,x5];
  97. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  98. y4=.25[x_height,h]; y5=.5[-d,y4];
  99. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  100. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  101. bulb(2,1,0); bulb(7,8,9);  % bulbs
  102. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
  103. filldraw z4r--z5l--z5r--z4l--cycle;  % left stem
  104. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
  105. top y11=h; filldraw stroke z11e--z12e;  % right stem
  106. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  107. top y20r=top y21r=x_height;
  108. lft x20=lft x4r-.5stem-u; x21=x11;
  109. filldraw stroke z20e--z21e;  %  crossbar
  110. penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,20,21,88,89); endchar;
  111.  
  112. cmchar "Italic ligature ffi";
  113. beginchar(oct"016",11.75u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
  114.  +4letter_fit#,asc_height#,desc_depth#);
  115. italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
  116. adjust_fit(0,0); pickup fine.nib;
  117. z98-z88=z99-z89=z14-z4=z15-z5=(5u+2letter_fit,0);
  118. numeric theta,mid_f;
  119. mid_f=.5[x88,x99]=.5(w-4.25u-2letter_fit); x89-x88=u;
  120. y98=h; y99=-d; theta=angle(z88-z89);
  121. pos21(stem,0); rt x21r=hround(w-2.5u+.5stem);
  122. x22=x21; x24=w; hook_out(22,23,24);  % closing hook
  123. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  124. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  125. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  126. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  127. rt x1r=hround(mid_f+1.75u); lft x8r=hround-.35u;
  128. x2=.5[x1,x4]; x7=.6[x8,x5];
  129. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  130. y4=.25[x_height,h]; y5=.5[-d,y4];
  131. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  132. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  133. bulb(2,1,0); bulb(7,8,9);  % left bulbs
  134. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper middle arc
  135. filldraw z4r--z5l--z5r--z4l--cycle;  % left stem
  136. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower left arc
  137. pos10(flare,0); pos11(hair,0); pos12(vair,90);
  138. pos13(.5[hair,stem],180); pos14(stem,theta+90);
  139. pos15(stem,theta-90); pos16(.5[hair,stem],0);
  140. pos17(vair,-90); pos18(hair,-180); pos19(flare,-180);
  141. x11r=x21r; lft x18r=hround(mid_f-1.25u); x12=.5[x11,x14]; x17=.5[x18,x15];
  142. x13=.8[x12+x14-x98,x98]; x16=.8[x17+x15-x99,x99];
  143. y10+.5flare=vround .85[x_height,h];
  144. y2=y12; y3=y13; y6=y16; y7=y17; y9=y19;
  145. bulb(12,11,10); bulb(17,18,19);  % right bulbs
  146. filldraw stroke z12e{left}...z13e...{z99-z98}z14e;  % upper right arc
  147. filldraw z14r--z15l--z15r--z14l--cycle;  % middle stem
  148. filldraw stroke z15e{z99-z98}...z16e...{left}z17e;  % lower middle arc
  149. top y21=x_height; filldraw stroke z21e--z22e;  % right stem
  150. pickup crisp.nib; pos30(bar,90); pos31(bar,90);
  151. top y30r=top y31r=x_height;
  152. lft x30=lft x4r-.5stem-u; x31=x21;
  153. filldraw stroke z30e--z31e;  %  crossbar
  154. penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,
  155.  20,21,22,23,24,30,31,88,89,98,99); endchar;
  156.  
  157. cmchar "Italic ligature ffl";
  158. beginchar(oct"017",12u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
  159.  +4letter_fit#,asc_height#,desc_depth#);
  160. italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
  161. adjust_fit(0,0); pickup fine.nib;
  162. z98-z88=z99-z89=z14-z4=z15-z5=(5u+2letter_fit,0);
  163. numeric theta,mid_f;
  164. mid_f=.5[x88,x99]=.5(w-4.5u-2letter_fit); x89-x88=u;
  165. y98=h; y99=-d; theta=angle(z88-z89);
  166. pos21(stem,0); rt x21r=hround(w-2.5u+.5stem);
  167. x22=x21; x24=w; hook_out(22,23,24);  % closing hook
  168. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  169. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  170. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  171. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  172. rt x1r=hround(mid_f+1.25u); lft x8r=hround-.35u;
  173. x2=.5[x1,x4]; x7=.6[x8,x5];
  174. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  175. y4=.25[x_height,h]; y5=.5[-d,y4];
  176. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  177. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  178. bulb(2,1,0); bulb(7,8,9);  % left bulbs
  179. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper middle arc
  180. filldraw z4r--z5l--z5r--z4l--cycle;  % left stem
  181. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower left arc
  182. pos10(flare,0); pos11(hair,0); pos12(vair,90);
  183. pos13(.5[hair,stem],180); pos14(stem,theta+90);
  184. pos15(stem,theta-90); pos16(.5[hair,stem],0);
  185. pos17(vair,-90); pos18(hair,-180); pos19(flare,-180); rt x11r=lft x21l;
  186. lft x18r=hround(mid_f-1.25u); x12=.5[x11,x14]; x17=.5[x18,x15];
  187. x13=.8[x12+x14-x98,x98]; x16=.8[x17+x15-x99,x99];
  188. y0=y10; y2=y12; y3=y13; y6=y16; y7=y17; y9=y19;
  189. bulb(12,11,10); bulb(17,18,19);  % right bulbs
  190. filldraw stroke z12e{left}...z13e...{z99-z98}z14e;  % upper right arc
  191. filldraw z14r--z15l--z15r--z14l--cycle;  % middle stem
  192. filldraw stroke z15e{z99-z98}...z16e...{left}z17e;  % lower middle arc
  193. top y21=h; filldraw stroke z21e--z22e;  % right stem
  194. pickup crisp.nib; pos30(bar,90); pos31(bar,90);
  195. top y30r=top y31r=x_height;
  196. lft x30=lft x4r-.5stem-u; x31=x21;
  197. filldraw stroke z30e--z31e;  %  crossbar
  198. penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,
  199.  20,21,22,23,24,30,31,88,89,98,99); endchar;
  200.